Лингрин :: Резиденция Линды Кайе

суббота, 18 июля 2009

11:28

Тотальная неудачница и убийца жёстких дисков.

#post-id: 3278-13-24
#original-date: 17.07.2009 Fri
#original-time: 1:24 PM
#original-day: 3278
#original-host: WinXP Prof SP1 (Build 2600)

А вот тут идёт вялое обсуждение службы женщин в армии.

http://newsforums.bbc.co.uk/ws/ru/thread.jspa?forumID=9362

От себя скажу, что ни чего плохого в этом не вижу.

Служба женщин в Армии - понятие исключительное, граничащее с моральным извращением в обществе. И если женщине приходится брать в руки оружие, то это может быть в исключительных случаях.

Ну да. А также исключительными моральными извращениями можно назвать работу, спорт, ношение открытой одежды. Неча светиться - марш на кухни! Товарищ это хотел сказать?

URL

11:28

Тотальная неудачница и убийца жёстких дисков.

#post-id: 3278-13-20
#original-date: 17.07.2009 Fri
#original-time: 1:20 PM
#original-day: 3278
#original-host: WinXP Prof SP1 (Build 2600)

Искала розу для газеты, нашла вот такую розу ^^'

http://ulibnis.kz/print:page,1,72-roza.html

URL

11:28

Тотальная неудачница и убийца жёстких дисков.

#post-id: 3278-12-44
#original-date: 17.07.2009 Fri
#original-time: 12:44 PM
#original-day: 3278
#original-host: WinXP Prof SP1 (Build 2600)

Хмммм... Раз уж в Windows NT планировщик такой невнятный, можно поюзать планировщик NOD32 ^^

URL

11:28

Тотальная неудачница и убийца жёстких дисков.

#post-id: 3277-21-59
#original-date: 16.07.2009 Thu
#original-time: 9:59 PM
#original-day: 3277
#original-host: WinXP Prof SP2 (Build 2600)

А вот и скрипт для настройки IE. Ускоряем любимый броузер ^_^

'====================================================================
' AJPapps - IE booster
' Линда Кайе 2009. Посвящается Ариэль
' 
' Этот скрипт настраивает количество одновременных подключений к 
' серверу в Internet Explorer. По умолчанию оно равно двум, что часто 
' существенно замедляет работу броузера. Скрипт поможет настроить это 
' значение.
' 
' http://support.microsoft.com/kb/282402
' 
' 16.07.2009 - первая версия ^^
'====================================================================
Option Explicit

Const AppTitle = "AJPapps - IE booster"

Dim Reg
Dim Path
Dim RC

Set Reg = CreateObject("WScript.Shell")
Path = "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\"

RC = MsgBox("AJPapps - Autorun quick tweak" & vbCrLf & _
            "Линда Кайе 2009. Посвящается Ариэль" & vbCrLf & vbCrLf & _
            "Этот скрипт настраивает количество одновременных " & _
            "подключений к серверу в Internet Explorer. По " & _
            "умолчанию оно равно двум, что часто существенно " & _
            "замедляет работу броузера. Скрипт поможет настроить " & _
            "это значение." & vbCrLf & vbCrLf & "Продолжить?", _
            vbOkCancel + vbQuestion, AppTitle)
If RC = vbCancel Then WScript.Quit

RC = MsgBox("Все настройки можно отменить, если что-то работает " & _
            "неправильно. Настроить параметры Internet Explorer?" & _
            vbCrLf & vbCrLf & _
            "Да     - продожить настройку." & vbCrLf & _
            "Нет    - удалить настроенные параметры." & vbCrLf & _
            "Отмена - выход.", _
            vbYesNoCancel + vbQuestion, AppTitle)
If RC = vbCancel Then WScript.Quit

If RC = vbNo Then
  RevertIE
Else
  GetMoreDetails
End If

MsgBox "Готово ^_^v", vbInformation, AppTitle
WScript.Quit

'====================================================================
Sub GetMoreDetails()
  Dim RC
  Dim TXT
  Dim Default
  
  Default = GetDefaultValue()
  TXT = InputBox("Введите количество соединений, которое " & _
                 "допускается делать Internet Explorer." & _
                 vbCrLf & vbCrLf & "Эта цифра подбирается " & _
                 "эмпирически, и слишком большое её значение " & _
                 "может вызвать перегрузку сервера, тормоза в " & _
                 "сети, глюки и прочие неприятные последствия. " & _
                 "Например при значении в 10 некоторые сайты " & _
                 "выдавали внутреннюю ошибку сервера." & vbCrLf & _
                 vbCrLf & "Я рекомендую 5, как компромиссный вариант.", _
                 AppTitle, Default)
  
  TXT = Trim(TXT)
  If TXT = "" Then WScript.Quit
  
  On Error Resume Next
  RC = CLng(TXT)
  
  If Err Or RC <= 0 Then
    MsgBox "Вы ввели неверное число. Оно должно быть больше нуля " & _
           "и не должно содержать посторонних символов.", vbCritical
    WScript.Quit
  End If
  
  SetupIE RC
End Sub

'====================================================================
Function GetDefaultValue()
  Dim RC
  
  ' Значение по умолчанию у нас такое ^^
  GetDefaultValue = 5
  
  On Error Resume Next
  
  RC = Reg.RegRead(Path & "MaxConnectionsPerServer")
  If Err Then Exit Function
  
  ' Тут должен был быть индусский код, но я решила его не писать ^^
  If GetType(RC) And vbLong Then
    If RC > 0 Then GetDefaultValue = RC
  End If
End Function

'====================================================================
Sub SetupIE(ByVal nConnections)
  On Error Resume Next
  
  Reg.RegWrite Path & "MaxConnectionsPer1_0Server", nConnections, "REG_DWORD"
  If Err Then
    MsgBox "Не удалось записать значение ""MaxConnectionsPer1_0Server""." & vbCrLf & vbCrLf & _
           "Error number: " & Err.Number & vbCrLf & _
           "Description:  " & Err.Description, vbCritical
    Err.Clear
  End If
  
  Reg.RegWrite Path & "MaxConnectionsPerServer", nConnections, "REG_DWORD"
  If Err Then
    MsgBox "Не удалось записать значение ""MaxConnectionsPerServer""." & vbCrLf & vbCrLf & _
           "Error number: " & Err.Number & vbCrLf & _
           "Description:  " & Err.Description, vbCritical
    Err.Clear
  End If
End Sub

'====================================================================
Sub RevertIE()
  On Error Resume Next
  
  Reg.RegDelete Path & "MaxConnectionsPer1_0Server"
  If Err Then
    MsgBox "Не удалось удалить значение ""MaxConnectionsPer1_0Server""." & vbCrLf & vbCrLf & _
           "Error number: " & Err.Number & vbCrLf & _
           "Description:  " & Err.Description, vbCritical
    Err.Clear
  End If
  
  Reg.RegDelete Path & "MaxConnectionsPerServer"
  If Err Then
    MsgBox "Не удалось удалить значение ""MaxConnectionsPerServer""." & vbCrLf & vbCrLf & _
           "Error number: " & Err.Number & vbCrLf & _
           "Description:  " & Err.Description, vbCritical
    Err.Clear
  End If
End Sub

#music: Fukuda Yasufumi\Murder Princess Original Soundtrack\Munasawagi kara Kakushin

URL